Excel函数进阶：SUMIFS与SUM结合常量数组实现复杂条件求和

Excel函数进阶：SUMIFS与SUM结合常量数组实现复杂条件求和

引用

CSDN

1.

https://blog.csdn.net/kl28978113/article/details/136369396

在Excel数据处理中，SUMIFS和SUM函数结合常量数组可以实现复杂的条件求和。本文通过具体案例，详细展示了如何使用这两种函数进行单条件、多条件以及涉及多个客户的销售额统计等操作。

我们有数据如下图：

需要针对此数据进行条件求和，条件如下：

题目一：求客户A销售额。

1. =SUMIF(A2:A10,"A",C2:C10)
2. =SUM((A2:A10="A")*C2:C10) 数组公式

题目二：客户A的1月份销售额。

1. =SUMIFS(C2:C10,A2:A10,"A",B2:B10,1)
2. =SUM((A2:A10="A")*(B2:B10=1)*C2:C10) 数组公式

题目三：客户A的1月份和3月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,"A",B2:B10,{1,3})) 数组公式
2. =SUM((A2:A10="A")*(B2:B10={1,3})*C2:C10) 数组公式

题目四：客户A和B销售额。

1. =SUM(SUMIF(A2:A10,{"A","B"},C2:C10)) 数组公式
2. =SUM((A2:A10={"A","B"})*C2:C10) 数组公式

题目五：客户A和客户C的1月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,{"A","C"},B2:B10,1)) 数组公式
2. =SUM((A2:A10={"A","C"})*(B2:B10=1)*C2:C10) 数组公式

题目六：客户A的1月份和客户C的3月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,{"A","C"},B2:B10,{1,3})) 数组公式
2. =SUM((A2:A10={"A","C"})*(B2:B10={1,3})*C2:C10) 数组公式

题目七：客户A和客户C的1月份和3月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,{"A","C"},B2:B10,{1;3})) 数组公式
2. =SUM((A2:A10={"A","A","C","C"})*(B2:B10={1,3,1,3})*C2:C10) 数组公式

题目八：客户A和客户C的1月/3月份/4月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,{"A","C"},B2:B10,{1;3;4})) 数组公式
2. =SUM((A2:A10={"A","A","A","C","C","C"})*(B2:B10={1,3,4,1,3,4})*C2:C10) 数组公式

题目九：客户A/B/C的1月/3月份/4月份销售额。

1. =SUM(SUMIFS(C2:C10,A2:A10,{"A","B","C"},B2:B10,{1;3;4})) 数组公式
2. =SUM((A2:A10={"A","A","A","B","B","B","C","C","C"})*(B2:B10={1,3,4,1,3,4,1,3,4})*C2:C10) 数组公式

在多条件求和情况下，sumifs函数比sum函数简便很多。但是当引用常量数组后，两个函数都会非常便捷。