FPGA极易入门教程：LED跑马灯（流水灯）实现详解

FPGA极易入门教程：LED跑马灯（流水灯）实现详解

本文主要介绍了FPGA入门教程中关于LED跑马灯（流水灯）的实现方法。通过详细讲解LED的基本原理、串行与并行实现的区别、具体实现代码、仿真测试以及上板测试等内容，帮助读者掌握FPGA的基本应用。

1. LED的基本原理

LED，又名发光二极管。LED灯工作电流很小（有的仅零点几毫安即可发光），抗冲击和抗震性能好，可靠性高，寿命长。由于这些优点，LED灯被广泛用在仪器仪表中作指示灯、液晶屏背光源等诸多领域。不同材料的发光二极管可以发出红、橙、黄、绿、青、蓝、紫、白这八种颜色的光。

上图是可以发出黄、红、蓝三种颜色的直插型二极管实物图，这种二极管长的一端是阳极，短的那端是阴极。

下图是开发板上用的贴片发光二极管实物图。贴片二极管的正面一般都有颜色标记，有标记的那端就是阴极。

发光二极管与普通二极管一样具有单向导电性。给它加上阳极正向电压后，通过5mA左右的电流就可以使二极管发光。通过二极管的电流越大，发出的光亮度越强。不过我们一般将电 流限定在3~20mA之间，否则电流过大就会烧坏二极管。

2. 串行与并行实现的区别

大多数开发板的LED都是设计成阴极接地，而阳极接到FPGA（或者单片机）的IO管脚上，所以我们只需要对IO口赋值即可实现LED的亮灭（赋值高电平==LED亮；赋值低电平==LED灭）。相信大多数同学都有C语言和单片机的基础（什么？你没有？那你还不去学），所以我们先来看一下单片机完成流水灯是怎么做的：

#include<reg52.h>
#define uchar  unsigned char
#define uint   unsigned int
sbit LED1 = P2^0;
sbit LED2 = P2^1;
sbit LED3 = P2^2;
sbit LED4 = P2^3;
sbit LED5 = P2^4;
sbit LED6 = P2^5;
sbit LED7 = P2^6;
sbit LED8 = P2^7;
void delay(uint z)
{
    uint x,y;
    for(x =0; x < z; x++)
        for(y =0; y <113; y++);
}
void main(void)
{
    while(1)
    {
        LED1 =0;//灯亮
        delay(1000);//持续亮1s
        LED1 =1;//灯灭
        delay(1000);//持续灭1s
        LED2 =0;
        delay(1000);
        LED2 =1;
        delay(1000);
        LED3 =0;
        delay(1000);
        LED3 =1;
        delay(1000);
        LED4 =0;//灯亮
        delay(1000);//持续亮1s
        LED4 =1;//灯灭
        delay(1000);//持续灭1s
    }
}

直接看main函数：串行设计的流水灯是怎么实现的呢？

1. 首先点亮第1个LED----延时1s----熄灭第1个LED；
2. 然后点亮第2个LED----延时1s----熄灭第2个LED；
3. 然后点亮第3个LED----延时1s----熄灭第3个LED；
4. 最后点亮第4个LED----延时1s----熄灭第4个LED；

可以看到整个结构都是顺序执行下来的，即符合单片的顺序结构，也非常契合人类的思维方式。那么FPGA不是顺序结构的，而是并行结构，无法直接一条一条指令地执行，那么该如何实现流水灯？

FPGA的工作是无法离开时钟的（组合逻辑除外）。我们可以设计一个always块，实现计数（或者说是计时）功能：每来一个时钟，让寄存器cnt的值累加1，直到加到预先设计的阈值再从0开始循环。假设FPGA的工作频率是50M，那么周期就是20ns。要实现计数到1s，则需要计数1s/20ns = 50_000_000次。所以我们的计时模块，就从0计数到50_000_000 – 1，即可实现计数1s。

同时我们再设计一个always块（LED显示），每当计数模块计数到了1s，就让LED的输出变化一次。比如初始显示最右边的LED，第1s到来时切换显示右边数第2个LED；第2s到来时切换显示右边数第3个LED；第3s到来时切换显示最左边的LED。这样就可以实现LED的流水显示了。

从上面的分析，可以通过流程图来直观感受串行设计与并行设计的不同：

3. 流水灯的具体实现

第二章实际上已经把流水灯的实现方法阐明了：

1. 构造一个计时器，循环计时1s
2. 构造显示的always块，每当计数器计时到1s，则切换LED显示状态

1s计时器

上面算了在50M的时钟频率下，计数到1s需要计数50000000次，这个数转换成二进制需要26位才能表示，所以寄存器cnt的位宽是26位，如下：

reg [25:0] cnt; //1s计时器
always @(posedge sys_clk or negedge sys_rst_n) begin
    if (!sys_rst_n)
        cnt <= 26'd0; //复位为0
    else if (cnt == 50_000_000 - 1) //计数到1s
        cnt <= 26'd0; //清零计数器
    else //计数不到1s
        cnt <= cnt + 1'd1; //计数器每个周期累加1
end

LED显示

每当计数器计时到1s，则切换LED显示状态：第一次只显示最右边的LED1，下一次显示LED2，再下一次显示LED3，下一次显示LED4，然后重复显示LED1，如此循环，如下图所示：

该部分代码如下：

always @(posedge sys_clk or negedge sys_rst_n) begin
    if (!sys_rst_n)
        led <= 4'b0001; //复位为最右边的点亮
    else if (cnt == 50_000_000 - 1) //计数到1s
        //拼接运算。把最高位（最左边的LED）移动到最低位，第2、1、0位作为整体向左移动一位
        led <= {led[2:0], led[3]};
    else //计数不到1s
        led <= led; //保持LED状态不变
end

需要注意的是：我们是使用移位运算符来实现LED的循环移位：把右边三位【2：0】变成高3位【3：1】，而最高位【3】变成最低位【0】，即可显示LED显示的整体左移。

完整代码如下：

//**************************************************************************
//***名称 : led_flow
//***作者 : 孤独的单刀
//***博客 : https://blog.csdn.net/wuzhikaidetb
//***日期 :2021.12
//***描述 :1s流水灯，循环左移
//**************************************************************************
module led_flow
//============================<信号>=====================================
(
    //时钟和复位 --------------------------------------------
    input sys_clk, //系统时钟50M
    input sys_rst_n, //低电平有效的异步复位
    //DDR3写 ------------------------------------------------
    output reg [3:0] led //LED的赋值电平
);
reg [25:0] cnt; //1s计时器
always @(posedge sys_clk or negedge sys_rst_n) begin
    if (!sys_rst_n)
        cnt <= 26'd0; //复位为0
    else if (cnt == 50_000_000 - 1) //计数到1s
        cnt <= 26'd0; //清零计数器
    else //计数不到1s
        cnt <= cnt + 1'd1; //计数器每个周期累加1
end
always @(posedge sys_clk or negedge sys_rst_n) begin
    if (!sys_rst_n)
        led <= 4'b0001; //复位为最右边的点亮
    else if (cnt == 50_000_000 - 1) //计数到1s
        //拼接运算。把最高位（最左边的LED）移动到最低位，第2、1、0位作为整体向左移动一位
        led <= {led[2:0], led[3]};
    else //计数不到1s
        led <= led; //保持LED状态不变
end
endmodule

4. 仿真测试

进行仿真测试的时候，我们把代码稍微改下：1s计时模块改成1ms计时模块，即50_000_000改为50_000。原因是若计时1s则仿真需要的时间太长。仿真的testbench比较简单，只需要提供时钟和复位激励即可，如下：

//**************************************************************************
//***名称 : tb_led_flow
//***作者 : 孤独的单刀
//***博客 : https://blog.csdn.net/wuzhikaidetb
//***日期 :2021.12
//***描述 :1s流水灯，循环左移的测试模块
//**************************************************************************
`timescale 1ns/1ns //时间单位/精度
//------------<模块及端口声明>----------------------------------------
module tb_led_flow();
reg sys_clk;
reg sys_rst_n;
wire [3:0] led;
//------------<例化被测试模块>----------------------------------------
led_flow led_flow_inst
(
    .sys_clk (sys_clk ),
    .sys_rst_n (sys_rst_n ),
    .led (led )
);
//------------<设置初始测试条件>----------------------------------------
initial begin
    sys_clk = 1'b0; //初始时钟为0
    sys_rst_n <= 1'b0; //初始复位
    #5 //5个时钟周期后
    sys_rst_n <= 1'b1; //拉高复位，系统进入工作状态
end
//------------<设置时钟>----------------------------------------------
always #10 sys_clk = ~sys_clk; //系统时钟周期20ns
endmodule

使用modelsim执行仿真，仿真结果如下：

可以看到：

• 4个led的初始结果是0001（1代表LED亮，0代表灭），所以此时最右边的LED1亮，其他LED熄灭
• 1ms（仿真为节省时间改为1ms，实际上板验证是1s）后led的值变成了0010，代表此时仅LED2亮，其他LED熄灭
• 再1ms后led的值变成了0100，代表此时仅LED3亮，其他LED熄灭
• 再1ms后led的值变成了1000，代表此时仅LED4亮，其他LED熄灭
• 再1ms后led的值变成了0001，代表此时仅LED1亮，其他LED熄灭
• 一直循环上面的状态，以此来实现LED的流水显示

5. 上板测试

绑定对应管脚，全编译整个文件，将sof文件通过JTAG接口下载进FPGA开发板，观察其实验现象。结果如下：

可以看到LED以1S的速度向左循环移位，实现了预期的流水灯效果。

6. 其他

版本信息

• 文件：V1.0
• 编号：0002
• Quartus II：Quartus II 13.1 (64-bit)
• Modelsim：Modelsim SE-64 2020.4