通达信公式系统

通达信公式系统

收阳、收阴

1. 当天收阳：

CLOSE>OPEN;

2. 当天收阴：

CLOSE<OPEN;

高开、低开

1. 当天股价高开，即开盘高于昨日收盘：

OPEN>REF(CLOSE,1);

2. 当天股价低开：

OPEN<REF(CLOSE,1);

上涨、下跌

1. 今日涨幅达到了7%以上：

CLOSE/REF(CLOSE,1)>1.07;

2. 十日均价继续上涨：

AA:=MA(CLOSE,10);
BB:=REE(AA,1);
AA>BB;

跳空

向上跳空：

OPEN>REF(HIGH,1);{当日开盘大于昨日最高价，为向上跳空}

向下跳空：

OPEN<REF(LOW,1);{当日开盘小于昨日最低价，为向下跳空}

创新高

创新高指当日最高价是最近一段时间的最高价：

HIGH=HHV(HIGH,N);

其中的HIGH为当期最高价，HHV(X,N)是求N周期内X最高值。因此该公式的含义是当日最高价创Ｎ日新高时返回值为1，否则为0。

横盘整理

横盘整理指最近一段时期价格在一定幅度之内摆动：

(HHV(CLOSE,10)-LLV(CLOSE,10))/CLOSE<0.05;

其中的LLV(X,N)是求N周期内X最低值。因此该公式表示10日收盘价振幅振幅在5%以内。

放量、缩量

1. 今日比昨日的成交量放大了1倍：

VOL/REF(VOL,1)>2;

2. 今日的五日均量比五天前的五日均量放大了3倍：

AA:=MA(VOL,5);
BB:=REF(AA,5);
AA/BB>4;

3. 今天的成交量达到了整个流通盘的10%以上：

VOL/CAPITAL>10/100; {注意，10%的表达式是10/100，或者0.1}

放量上攻

AA:=VOL/REF(VOL,1)>2;{成交量是昨日的两倍}
BB:=CLOSE/REF(CLOSE,1)>1.07;{涨幅大于7%}
AA AND BB;

高开高走

AA:=OPEN>REF(CLOSE,1)*1.02;
BB:=(OPEN=LOW) AND (HIGH>LOW) ;
AA AND BB;

向上跳空后2天内没有回补

定义：实际上就是昨天发生了跳空缺口，这两天的最低价一直在两天前的最高价之上。

AA:=REF(LOW,1)>REF(HIGH,2);
BB:=LOW>REF(HIGH,2);
AA AND BB;

5日、10日、30日均线多头排列

定义：均线多头排列，是指从短周期到长周期均线，从上而下的依次排列。

AA:=MA(CLOSE,5);
BB:=MA(CLOSE,10);
CC:=MA(CLOSE,30);
T1:=AA>BB AND BB>CC;
COUNT(T1,4)=4;{COUNT（X，N）表示统计在N天内满足条件X的有几天}

突破底部横盘整理创新高

定义：股价突破长期盘整区间，之后放量上攻进入主升段。

1. 长期：设定为150天；
2. 横盘：设定股价在150日均线上下15%波动；
3. 放量：将会使用5日均量来进行比较，成交量比昨日成交量放大两倍；
4. 历史新高：并且股价创下150天以来的历史新高。

公式编写：（参数M=150天）

{1.放量}
V1:=MA(VOL,5);       {V1是五日均量}
V2:=VOL/REF(V1,1)>2; {REF（V1,1）就是昨日的五日均量}
{2.长期横盘}
PZ1:=MA(CLOSE,M);    {PZ1是当天150日均价}
PZ2:=HHV(HIGH,M);    {PZ2是150日的最高价}
PZ3:=LLV(LOW,M);     {PZ3是150日的最低价}
PZ4:=(PZ2-PZ1)/PZ1;  {PZ4是150日的最高价和150日均价的距离的百分比}
PZ5:=(PZ1-PZ3)/PZ1;  {PZ5刚好相反是最低价和均价的差的百分比}
PZ:=REF(PZ4,1)<0.15 AND REF(PZ5,1)<0.15;   {设为股价在150日均线上下15%波动}
TP1:=HHV(HIGH,M);
TP:=HIGH=TP1;      {今天的最高价是150天内的最高价}
V2 AND PZ AND TP;    {综合三个条件}

逃顶K线形态-黄昏之星

黄昏之星是一个卖出信号，与之相对应的是一个买入信号，称为早晨之星，如下图：

黄昏之星定义：当市场出现一条大阳线后，通常会产生跳空高开的情况，有时便会出现十字星或类似十字星的小阴线（小阳线），当该形态出现在一段上升行情的当中，就很容易形成经典K线形态--黄昏之星。

1. 前天是一根低开高走的大阳线
2. 昨日K线的特征，是一根十字形态的K线，并且在左右两根K线之上
3. 今天是一根低开低走的大阴线，

REF(CLOSE,2)/REF(OPEN,2)>1.05 &&  {前日K线的特征：股价收阳，收盘较开盘高5%}
REF(OPEN,1)>REF(CLOSE,2) &&       {昨日跳开，高于前天的收盘}
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 &&  {昨日K线特征：实体较短；，即昨日开盘和收盘之差比昨日开盘的值小于0.03}
CLOSE/OPEN<0.95 &&                {今日K先特征：股价收阴，收盘价较开盘价低5%}
CLOSE<REF(CLOSE,2);               {今收小于2日前收盘}

如果我们想把这个选股公式改为指标公式，将以上条件赋值为
AA:=
，并增加一个语句
SELL((AA,HIGH*1.02);
即可。

AA:=REF(CLOSE,2)/REF(OPEN,2)>1.05 &&  {前日K线的特征：股价收阳，收盘较开盘高5%}
REF(OPEN,1)>REF(CLOSE,2) &&       {昨日跳开，高于前天的收盘}
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 &&  {昨日K线特征：实体较短；，即昨日开盘和收盘之差比昨日开盘的值小于0.03}
CLOSE/OPEN<0.95 &&                {今日K先特征：股价收阴，收盘价较开盘价低5%}
CLOSE<REF(CLOSE,2);               {今收小于2日前收盘}
SELL((AA,HIGH*1.02)

这时在符合条件的K线上方出现了一个绿色的向下箭头，提示卖出。效果如下：