批量调整图片尺寸方案（比例不变）

批量调整图片尺寸方案（比例不变）

引用

CSDN

1.

https://blog.csdn.net/weixin_40364882/article/details/134187854

最近又有一个问题，需要把一堆图片调整成统一的尺寸大小（例如100*100像素）。

网上或者很多工具都是直接把图片尺寸调整到对应尺寸。这就出现了一个问题——整个图片会被压缩拉伸，图片里的物体/人等都变形了。

原图（200*270）：

直接调整尺寸后（200*200）：

我们需要的效果是把它置入到200*200像素的画布中：

虽然有一些多余的区域，但能保证原图比例不变，能看的清楚图片是什么东西。

当然只有一两张图的话，我建议用

方案一：

1. 打开PS，新建一个指定尺寸的画布（背景要什么颜色或者透明自行决策）。
2. 把原图片置入到画布中，再导出另存为图片即可。

但方案一有缺点：

1. 只能少量图片操作。
2. 不能覆盖回原来的图片，只能另存。

所以经过几个小时的思考，想出了一个最佳的解决方案：使用系统批处理命令行代码来实现。只需调整输入文件夹目录、输出文件夹目录、以及画布尺寸大小即可。不过此代码还使用到了ImageMagick软件。这个提前安装好就能解决了。

@echo off
setlocal enabledelayedexpansion
set "input_folder=C:\Users\Administrator\Desktop\test"
set "output_folder=C:\Users\Administrator\Desktop\test"
set "canvas_width=300"
set "canvas_height=375"
for /R "%input_folder%" %%F in (*.JPG *.jpeg *.png) do (
    set "input_file=%%~dpnxF"
    set "output_file=%output_folder%\%%~nxF"
    rem 获取原图片的尺寸
    for /F "usebackq tokens=1,2" %%A in (`magick identify -format "%%w %%h" "!input_file!"`) do (
        set "original_width=%%A"
        set "original_height=%%B"
    )
    rem 计算缩放比例
    set /A "scale_width=!canvas_width! * 100 / !original_width!"
    set /A "scale_height=!canvas_height! * 100 / !original_height!"
    rem 取较小的缩放比例
    if !scale_width! gtr !scale_height! (
        set "scale=!scale_height!"
    ) else (
        set "scale=!scale_width!"
    )
    rem 计算缩放后的尺寸
    set /A "scaled_width=!original_width! * !scale! / 100"
    set /A "scaled_height=!original_height! * !scale! / 100"
    rem 计算在画布上居中的位置
    set /A "position_x=(!canvas_width! - !scaled_width!) / 2"
    set /A "position_y=(!canvas_height! - !scaled_height!) / 2"
    rem 使用 ImageMagick 软件将原图片缩放并放置在画布上
    magick convert "!input_file!" -resize !scaled_width!x!scaled_height! -gravity center -background white -extent !canvas_width!x!canvas_height! "!output_file!"
)
endlocal