Halcon圆形测量工具详解：从图像读取到结果可视化

Halcon圆形测量工具详解：从图像读取到结果可视化

本文将详细介绍如何使用Halcon软件进行圆形测量。通过读取图像、阈值分割、区域转换、设置测量模式、实际测量以及结果可视化等多个步骤，帮助读者掌握这一重要功能。

最近接到了一个关于带洞圆环测量的需求，需要检测圆环洞口的宽度。虽然Halcon自带的助手可以直接实现这一功能，但为了帮助大家更好地理解，我将通过自定义代码来完成这一任务。

一、读取图像

首先，我们需要读取待处理的图像。假设图像存储在本地路径E:/boke/1.png。

read_image (Image, 'E:/boke/1.png')
get_image_size (Image, Width, Height)

二、阈值分割提取洞口区域

为了准确测量洞口的宽度，我们先提取外轮廓，再提取洞口区域。

binary_threshold (Image, Region_All, 'max_separability', 'light', UsedThreshold)
connection (Region_All, Region_Base)

三、将洞口区域转换为二值图像

将提取到的区域转换为二值图像，便于后续测量。

smallest_circle (Region_Base, Row_Base, Column_Base, Radius_Base)
fill_up (Region_Base, Region_Base_Fill)
difference (Region_Base_Fill, Region_Base, Region_Holes)
connection (Region_Holes, Region_Holes)
select_shape (Region_Holes, Region_Holes, 'area', 'and', 3000, 5000)
union1 (Region_Holes, Region_Holes)
region_to_bin (Region_Holes, BinImage, 255, 0, Width, Height)

四、设置测量模式和基本参数

测量模式分为两种：测量洞口宽度（A）和测量相邻两个洞口的宽度（B）。

IsChooseBackGround:=true

五、测量

1. 生成可视化检测圆形

set_system ('int_zooming', 'true')
draw_circle (200000, MeasureC_R, MeasureC_C, MeasureC_Radius)

2. 生成检测圆并输出工具句柄

MeasureC_R := 550.79
MeasureC_C := 697.792
MeasureC_Radius := 422.744
gen_circle (Region_MeasureC, MeasureC_R, MeasureC_C, MeasureC_Radius)
gen_contour_region_xld (Region_MeasureC, Region_MeasureC, 'border')
gen_region_contour_xld (Region_MeasureC, Region_MeasureC, 'margin')
gen_measure_arc (MeasureC_R, MeasureC_C, MeasureC_Radius, rad(0), rad(360), max2(1, min2(56.5, MeasureC_Radius)), 1280, 1024, 'nearest_neighbor', MsrHandle)

3. 测量获得数据

measure_pairs (BinImage, MsrHandle, 1, 36, 'positive', 'all', Row1_Measure_01_0, Column1_Measure_01_0, Amplitude1_Measure_01_0, Row2_Measure_01_0, Column2_Measure_01_0, Amplitude2_Measure_01_0, Width_Measure_01_0, Distance_Measure_01_0)
close_measure (MsrHandle)
gen_cross_contour_xld (Cross_SP, Row1_Measure_01_0, Column1_Measure_01_0, 20, 0.785398)
gen_cross_contour_xld (Cross_EP, Row2_Measure_01_0, Column2_Measure_01_0, 20, 0.785398)
if(IsChooseBackGround)
    intersection (Region_Holes, Region_MeasureC, Region_LineShow)
    Res:=Width_Measure_01_0
else
    difference (Region_MeasureC, Region_Holes, Region_LineShow)
    Res:=Distance_Measure_01_0
endif

4. 可视化和数据计算显示

OutModel:=2
if(OutModel==1)
    tuple_mean (Res, Result)
    message:='平均距离'
elseif(OutModel==2)
    tuple_min (Res, Result)
    message:='最大距离'
elseif(OutModel==3)
    tuple_max (Res, Result)
    message:='最小距离'
endif
dev_clear_window ()
dev_set_line_width (2)
dev_display (Image)
dev_set_draw ('margin')
dev_set_color ('red')
dev_display (Cross_SP)
dev_set_color ('green')
dev_display (Cross_EP)
dev_set_color ('blue')
dev_display (Region_LineShow)
dev_set_color ('red')
disp_message (200000, message+':'+Result, 'image', 10, 10, 'green', 'false')

六、最终显示效果

通过上述步骤，我们可以得到准确的测量结果，并在图像上直观地显示出来。