Excel 公式查找一列中的重复项（8 种简单方法）
Excel 公式查找一列中的重复项（8 种简单方法）
在Excel中查找重复项是数据处理中的常见需求。本文将介绍8种不同的方法，帮助用户快速定位并处理重复数据。从简单的公式应用到复杂的条件判断，这些方法涵盖了从基础到进阶的各种场景，适合不同层次的Excel用户参考使用。
方法 1 – 使用 COUNTIF 函数查找一列中的重复项以及第一次出现的项
我们在 B 列中有一个名称列表。查找重复项的公式对于重复名称将返回TRUE，对于 C 列中的唯一名称将返回FALSE。
- 在第一个结果单元格 (C5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=COUNTIF($B$5:$B$14,B5)>1
COUNTIF函数返回每个名称的计数（第二个参数）。逻辑运算符检查大于1的计数。
方法 2 – 使用 IF 和 COUNTIF 函数创建Excel公式以查找一列中的重复项
在输出标题下，公式将为B 列中出现的重复名称返回重复。
- 在第一个结果单元格 (C5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=IF(COUNTIF($B$5:$B$14,B5)>1,"Duplicate","")
IF函数包装方法 1 中的公式，以返回指定的文本重复或空白值。
方法 3 – 在Excel中查找一列中没有第一次出现的重复项
仅当某个值之前已经重复过时（即第一次出现时将得到空白结果），该公式才会显示重复。
- 在第一个结果单元格 (C5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=IF(COUNTIF($B$5:$B5,B5)>1,"Duplicate","")
对于单元格C5中的第一个输出，我们使用**$B$5:$B5定义了单元格范围，因此第二行引用随公式移动。对于每个后续输出，COUNTIF函数的定义范围中的单元格数量会增加1**。这确保第一个值只会被计算一次。
方法 4 – 使用Excel公式查找单列中区分大小写的重复项
- 在第一个结果单元格 (C5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=IF(SUM((--EXACT($B$5:$B$14,B5)))<=1,"","Duplicate")
公式如何运作？
- 这里的EXACT函数会查找“名称”列中第一个文本的区分大小写且完全匹配的内容，从而返回以下输出：
{TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}
- 通过使用双一元 (-)，返回值 TRUE 和 FALSE 转换为数字 1 和 0。因此，这里的返回值将是：
{1;0;0;0;0;0;0;0;0;0}
然后，SUM函数对上一步中找到的所有数值求和。
=SUM((–EXACT($B$5:$B$14, B5)))<=1:这部分公式检查上一步中找到的总和或返回值是否相等至或小于1。
IF函数查找小于或等于1的总和并返回空白单元格，如果未找到，则返回定义的文本重复>。
方法 5 – 查找某个值在列中重复的次数
- 在第一个结果单元格 (C5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=COUNTIF($B$5:$B5,B5)
此公式类似于用于检查重复项（没有第一次出现）的公式，第二个引用随公式移动。 COUNTIF 函数自然会返回一个数字，因此我们不需要更多的检查。
方法6 – 在Excel中过滤并删除一列中的重复项
我们使用方法 5 来获取每个值出现的序列号。
步骤：
选择整个表格，包括其标题。
在主页选项卡下，从编辑组中的排序和过滤下拉列表中选择选项过滤命令。
- 这将激活标题的过滤器按钮。
单击输出下拉列表并取消标记1。
单击“确定”。
您将获得重复值的列表。
选择这些单元格并将其删除。
再次打开输出过滤器。
仅标记选项1。
单击“确定”。
您将仅获得所有唯一的文本数据或名称。具有空白值的单元格已被过滤器隐藏。您可以稍后删除这些行。
方法 7 – 创建Excel公式以根据条件查找一列中的重复项
我们还有一个附加列，代表组织中所有员工的部门。我们将检查名称和部门的组合是否重复。
- 在第一个结果单元格 (D5) 中插入以下公式，然后按Enter并使用自动填充获取整个列的结果。
=IF(COUNTIFS($B$5:$B$14,B5,$C$5:$C$14,C5)>1,"Duplicate","")
- 这是结果。
COUNTIFS函数隐式使用所有条件及其范围之间的 AND 参数。
方法 8 – 使用条件格式查找并突出显示重复项
选择B 列中名称标题下的所有名称。
在主页功能区下，从条件格式下拉列表中选择新规则选项。
将出现一个名为新格式规则的对话框。
选择规则类型为使用公式确定要设置格式的单元格。
在规则说明框中，插入以下公式：
=COUNTIF($B$5:$B$14,B5)>1
按格式化。
在设置单元格格式窗口中，切换到填充选项卡，然后为重复单元格选择背景颜色。
按确定。
您将看到单元格格式的预览，如下图所示。单击确定。
该公式突出显示所有重复项，包括其第一次出现的情况。您可以使用不同的公式仅突出显示第一个公式之后出现的情况（请参阅方法 3）。